86 lines
2.8 KiB
Solidity
86 lines
2.8 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
// OpenZeppelin Contracts (last updated v5.5.0) (utils/ReentrancyGuardTransient.sol)
|
|
|
|
pragma solidity ^0.8.24;
|
|
|
|
import {TransientSlot} from "./TransientSlot.sol";
|
|
|
|
/**
|
|
* @dev Variant of {ReentrancyGuard} that uses transient storage.
|
|
*
|
|
* NOTE: This variant only works on networks where EIP-1153 is available.
|
|
*
|
|
* _Available since v5.1._
|
|
*
|
|
* @custom:stateless
|
|
*/
|
|
abstract contract ReentrancyGuardTransient {
|
|
using TransientSlot for *;
|
|
|
|
// keccak256(abi.encode(uint256(keccak256("openzeppelin.storage.ReentrancyGuard")) - 1)) & ~bytes32(uint256(0xff))
|
|
bytes32 private constant REENTRANCY_GUARD_STORAGE =
|
|
0x9b779b17422d0df92223018b32b4d1fa46e071723d6817e2486d003becc55f00;
|
|
|
|
/**
|
|
* @dev Unauthorized reentrant call.
|
|
*/
|
|
error ReentrancyGuardReentrantCall();
|
|
|
|
/**
|
|
* @dev Prevents a contract from calling itself, directly or indirectly.
|
|
* Calling a `nonReentrant` function from another `nonReentrant`
|
|
* function is not supported. It is possible to prevent this from happening
|
|
* by making the `nonReentrant` function external, and making it call a
|
|
* `private` function that does the actual work.
|
|
*/
|
|
modifier nonReentrant() {
|
|
_nonReentrantBefore();
|
|
_;
|
|
_nonReentrantAfter();
|
|
}
|
|
|
|
/**
|
|
* @dev A `view` only version of {nonReentrant}. Use to block view functions
|
|
* from being called, preventing reading from inconsistent contract state.
|
|
*
|
|
* CAUTION: This is a "view" modifier and does not change the reentrancy
|
|
* status. Use it only on view functions. For payable or non-payable functions,
|
|
* use the standard {nonReentrant} modifier instead.
|
|
*/
|
|
modifier nonReentrantView() {
|
|
_nonReentrantBeforeView();
|
|
_;
|
|
}
|
|
|
|
function _nonReentrantBeforeView() private view {
|
|
if (_reentrancyGuardEntered()) {
|
|
revert ReentrancyGuardReentrantCall();
|
|
}
|
|
}
|
|
|
|
function _nonReentrantBefore() private {
|
|
// On the first call to nonReentrant, REENTRANCY_GUARD_STORAGE.asBoolean().tload() will be false
|
|
_nonReentrantBeforeView();
|
|
|
|
// Any calls to nonReentrant after this point will fail
|
|
_reentrancyGuardStorageSlot().asBoolean().tstore(true);
|
|
}
|
|
|
|
function _nonReentrantAfter() private {
|
|
_reentrancyGuardStorageSlot().asBoolean().tstore(false);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
|
|
* `nonReentrant` function in the call stack.
|
|
*/
|
|
function _reentrancyGuardEntered() internal view returns (bool) {
|
|
return _reentrancyGuardStorageSlot().asBoolean().tload();
|
|
}
|
|
|
|
function _reentrancyGuardStorageSlot() internal pure virtual returns (bytes32) {
|
|
return REENTRANCY_GUARD_STORAGE;
|
|
}
|
|
}
|
|
|